home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / nan_news / toolkit / week.prg < prev    next >
Text File  |  1991-08-15  |  4KB  |  114 lines
  1. /*
  2.  * File......: WEEK.PRG
  3.  * Author....: Jo W. French dba Practical Computing
  4.  * CIS ID....: 74731,1751
  5.  * Date......: $Date:   15 Aug 1991 23:05:26  $
  6.  * Revision..: $Revision:   1.2  $
  7.  * Log file..: $Logfile:   E:/nanfor/src/week.prv  $
  8.  * 
  9.  * The functions contained herein are the original work of Jo W. French
  10.  * and are placed in the public domain.
  11.  *
  12.  * Modification history:
  13.  * ---------------------
  14.  *
  15.  * $Log:   E:/nanfor/src/week.prv  $
  16.  * 
  17.  *    Rev 1.2   15 Aug 1991 23:05:26   GLENN
  18.  * Forest Belt proofread/edited/cleaned up doc
  19.  * 
  20.  *    Rev 1.1   14 Jun 1991 19:53:16   GLENN
  21.  * Minor edit to file header
  22.  * 
  23.  *    Rev 1.0   01 Apr 1991 01:02:30   GLENN
  24.  * Nanforum Toolkit
  25.  *
  26.  */
  27.  
  28. /*  $DOC$
  29.  *  $FUNCNAME$
  30.  *     FT_WEEK()
  31.  *  $CATEGORY$
  32.  *     Date/Time
  33.  *  $ONELINER$
  34.  *     Return calendar or fiscal week data
  35.  *  $SYNTAX$
  36.  *     FT_WEEK( [ <dGivenDate> ], [ <nWeekNum> ] ) -> aDateinfo
  37.  *  $ARGUMENTS$
  38.  *     <dGivenDate> is any valid date in any date format.  Defaults
  39.  *     to current system date if not supplied.
  40.  *
  41.  *     <nWeekNum> is a number from 1 to 53 signifying a week.
  42.  *     Defaults to current week if not supplied.
  43.  *  $RETURNS$
  44.  *     A three element array containing the following data:
  45.  *
  46.  *        aDateInfo[1] - The year and week as a character string "YYYYWW"
  47.  *        aDateInfo[2] - The beginning date of the week
  48.  *        aDateInfo[3] - The ending date of the week
  49.  *  $DESCRIPTION$
  50.  *     FT_WEEK() returns an array containing data about the week
  51.  *     containing the given date.
  52.  *
  53.  *     Normally the return data will be based on a year beginning
  54.  *     on January 1st with weeks beginning on Sunday.
  55.  *
  56.  *     The beginning of year date and/or beginning of week day can be
  57.  *     changed by using FT_DATECNFG(), which will affect all subsequent
  58.  *     calls to FT_WEEK() until another call to FT_DATECNFG().
  59.  *
  60.  *     The beginning of year date and beginning of week day may be reset
  61.  *     to January 1 and Sunday by calling FT_DATECNFG() with no
  62.  *     parameters.
  63.  *  $EXAMPLES$
  64.  *     // get info about week containing 9/15/90
  65.  *     aDateInfo := FT_WEEK( CTOD("09/15/90") )
  66.  *     ? aDateInfo[1]   //  199037       (37th week)
  67.  *     ? aDateInfo[2]   //  09/09/90     beginning of week 37
  68.  *     ? aDateInfo[3]   //  09/15/90     end of week 37
  69.  *
  70.  *     // get info about week 25 in year containing 9/15/90
  71.  *     aDateInfo := FT_WEEK( CTOD("09/15/90"), 25 )
  72.  *     ? aDateInfo[1]   //  199025
  73.  *     ? aDateInfo[2]   //  06/17/90   beginning of week 25
  74.  *     ? aDateInfo[3]   //  06/23/90   end of week 25
  75.  *
  76.  *     // get info about week 25 in current year
  77.  *     aDateInfo := FT_WEEK( , 25 )
  78.  *     ? aDateInfo[1]   //  199025
  79.  *     ? aDateInfo[2]   //  06/16/91   beginning of week 25
  80.  *     ? aDateInfo[3]   //  06/22/91   end of week 25
  81.  *  $SEEALSO$
  82.  *     FT_DATECNFG() FT_MONTH() FT_QTR() FT_YEAR()
  83.  *  $END$
  84. */
  85.  
  86. FUNCTION FT_WEEK(dGivenDate,nWeekNum)
  87. LOCAL lIsWeek, nTemp, aRetVal
  88.  
  89.   IF dGivenDate == NIL .OR. !VALTYPE(dGivenDate) $ 'ND'
  90.      dGivenDate := DATE()
  91.   ELSEIF VALTYPE(dGivenDate) == 'N'
  92.      nWeekNum := dGivenDate
  93.      dGivenDate := DATE()
  94.   ENDIF
  95.  
  96.   lIsWeek := IF(nWeekNum == NIL .OR. VALTYPE(nWeekNum) != 'N', .F., .T.)
  97.  
  98.   aRetVal := FT_YEAR(dGivenDate)
  99.  
  100.   IF lIsWeek
  101.      nTemp := INT( (aRetVal[3] - aRetVal[2]) / 7 ) + 1
  102.      nWeekNum := IF(nWeekNum > 0 .AND. nWeekNum <= nTemp , nWeekNum, nTemp)
  103.      dGivenDate := aRetVal[2] + (nWeekNum - 1) * 7
  104.   ENDIF
  105.  
  106.   aRetVal[1] += PADL(LTRIM(STR(INT( (dGivenDate - ;
  107.                  aRetVal[2]) / 7 ) + 1, 2)), 2, '0')
  108.   dGivenDate += ( 6 - FT_DAYTOBOW(dGivenDate) )       // end of week
  109.   aRetVal[2] := dGivenDate - 6
  110.   aRetVal[3] := IIF(dGivenDate > aRetVal[3], aRetVal[3], dGivenDate)
  111.  
  112. RETURN aRetVal
  113.  
  114.